*
* Je change le filetype des fichiers
*

 lst off
 rel
 dsk ChangeType.l

*--- Entre chaque disquette, attente clavier

binTYPE = $06
dirTYPE = $0f
proDOS = $e100a8

*---

 phk
 plb

 clc
 xce
 rep #$30

* Disk 1

 lda #pDATA
 jsr handleTYPE

 lda #pMUSIC
 jsr handleTYPE

 jsr waitKEY

* Disk 2

 lda #pLVL2
 jsr handleTYPE

 jsr waitKEY

* Disk 3

 lda #pLVL3
 jsr handleTYPE

* Sortie

 jsl proDOS
 dw $2029
 adrl proQUIT

 brk
 brk

*---

waitKEY ldal $e0bfff
 bpl waitKEY
 stal $e0c00f
 rts

*---

pDATA strl '/LemminGS.Disk1/LemminGS.Data'
pMUSIC strl '/LemminGS.Disk1/LemminGS.Data/Music'

pLVL2 strl '/LemminGS.Disk2/LemminGS.Data/LVL'
pLVL3 strl '/LemminGS.Disk3/LemminGS.Data/LVL'

*---

handleTYPE sta proSETPFX+4
 sta proOPEN+4

 jsl proDOS
 dw $2009
 adrl proSETPFX

 jsl proDOS
 dw $2010
 adrl proOPEN

 lda proOPEN+2
 sta proGETDIR+2
 sta proCLOSE+2

 lda #1
 sta proGETDIR+6
 sta proGETDIR+8

handleTYPE1 jsl proDOS
 dw $201c
 adrl proGETDIR
 cmp #$61
 beq handleTYPE2

 jsl proDOS ; Get File Info
 dw $2006
 adrl proGETINFO

 lda proTYPE
 cmp #dirTYPE
 beq handleTYPE1

 lda #binTYPE ; Clear TYPE+AUXTYPE
 sta proTYPE

 stz proAUX
 stz proAUX+2

 jsl proDOS ; Set File Info
 dw $2005
 adrl proGETINFO

 bra handleTYPE1

*--- Sortie

handleTYPE2 jsl proDOS
 dw $2014
 adrl proCLOSE
 rts

*---

proSETPFX dw 2
 dw 0
 adrl pDATA

proOPEN dw 4
 ds 2
 adrl pDATA
 ds 2
 ds 2

proGETDIR dw 5
 ds 2
 ds 2
 dw 1
 ds 2
 adrl nameBUFFER

proGETINFO dw 12
 adrl nameBUFFER1
 ds 2
proTYPE ds 2
proAUX ds 4
 ds 2
 ds 8
 ds 8
 ds 4
 ds 4
 ds 4
 ds 4
 ds 4

proCLOSE dw 1
 ds 2

proQUIT dw 2
 ds 4
 ds 2

nameBUFFER dw 130
nameBUFFER1 ds 128
